<xsl:otherwise> |
Diese Anweisung definiert den else- oder default-Fall in einem <xsl:choose>-Element. Dieses Element kommt immer innerhalb eines <xsl:choose>-Elements vor und muss immer als Letztes erscheinen.
Kategorie
Untergeordnete Anweisung (<xsl:otherwise> kommt immer als Teil eines <xsl:choose>-Elements vor)
Obligatorische Attribute
Keine
Optionale Attribute
Keine
Inhalt
Eine Vorlage.
Übergeordnetes Element
<xsl:choose>
Definition
XSLT-Abschnitt 9.2, Bedingte Verarbeitung mit xsl:choose
Beispiel
Als Beispiel wird ein <xsl:choose>-Element verwendet, das einen Satz an Werten für die Hintergrundfarbe einer Zelle in einer HTML-Tabelle durchschreitet. Als Eingabe dient das folgende XML-Dokument:
    <?xml version="1.0"?>
    <list xml:lang="en">
      <title>Albums I've bought recently:</title>
      <listitem>The Sacred Art of Dub</listitem>
      <listitem>Only the Poor Man Feel It</listitem>
      <listitem>Excitable Boy</listitem>
      <listitem xml:lang="sw">Aki Special</listitem>
      <listitem xml:lang="en-gb">Combat Rock</listitem>
      <listitem xml:lang="zu">Talking Timbuktu</listitem>
      <listitem xml:lang="jz">The Birth of the Cool</listitem>
    </list>
Es folgt das Stylesheet, das <xsl:choose> innerhalb eines <xsl:attribute>-Elements verwendet, um den korrekten Wert für das Attribut bgcolor zu bestimmen. Das Stylesheet enthält ein <xsl:otherwise>-Element, das für jedes vierte <listitem> im Ausgangsdokument den Wert whitesmoke erzeugt.
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="html"/>

      <xsl:template match="/">
        <html>
          <head>
            <title>
              <xsl:value-of select="list/title"/>
            </title>
          </head>
          <body>
            <h1><xsl:value-of select="list/title"/></h1>
            <table border="1">
              <xsl:for-each select="list/listitem">
                <tr>
                  <td>
                    <xsl:attribute name="bgcolor">
                      <xsl:choose>
                        <xsl:when test="@bgcolor">
                          <xsl:value-of select="@bgcolor"/>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 0">
                          <xsl:text>papayawhip</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 1">
                          <xsl:text>mintcream</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 2">
                          <xsl:text>lavender</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:text>whitesmoke</xsl:text>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    <xsl:value-of select="."/>
                  </td>
                </tr>
              </xsl:for-each>
            </table>
          </body>
        </html>
      </xsl:template>

    </xsl:stylesheet>
Unten sehen Sie das generierte HTML-Dokument. Beachten Sie, dass jede vierte Zeile die Hintergrundfarbe whitesmoke besitzt. Dieser Wert wurde durch das <xsl:otherwise>-Element erzeugt.
    <html>
    <head>
    <META http-equiv="Content-Type" content="text/html; charset=UTF-8">
    <title>Albums I've bought recently:</title>
    </head>
    <body>
    <h1>Albums I've bought recently:</h1>
    <table border="1">
    <tr>
    <td bgcolor="mintcream">The Sacred Art of Dub</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Only the Poor Man Feel It</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">Excitable Boy</td>
    </tr>
    <tr>
    <td bgcolor="papayawhip">Aki Special</td>
    </tr>
    <tr>
    <td bgcolor="mintcream">Combat Rock</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Talking Timbuktu</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">The Birth of the Cool</td>
    </tr>
    </table>
    </body>
    </html>
Wie das HTML-Dokument in einem Browser angezeigt wird, sehen Sie in Abbildung A-7. Dokument-Cycling unter verschiedenen Hintergrundfarben